Galactic Empire - 1.05 released!

Quote from: Lachie Dazdarian on January 03, 2009, 05:11:25 PM

Gah.

I get "The application failed to initialized properly (0x0150002)" message with the trailer.

If you find the problem, please provide the download only with the exe too.

Duh, works perfectly fine for me so I can't tell. I usually don't check if initializations are sucessfull..
I guess it's best to post the code so you can compile it yourself and see what's wrong.

Code: Select All | Copy To Clipboard

Dim As Integer fullscreen = 0

#Include Once "SFML/Graphics.bi"
#Include Once "SFML/Audio.bi"
#Include Once "GL/gl.bi"
#Include Once "GL/glu.bi"

Dim Shared As sfWindowSettings Settings => (24, 8, 2)
Dim Shared As sfVideoMode Mode => (1024, 768, 32)
Dim Shared As sfRenderWindow Ptr App
Dim Shared As sfSprite Ptr Background, Title, Cursor, History
Dim Shared As sfClock Ptr Clock
Dim Shared As sfEvent Event
Dim Shared As sfString Ptr Text
Dim Shared As sfImage Ptr Image
Dim Shared As sfMusic Ptr Music
Dim Shared As sfShape Ptr shape
Dim Shared As sfInput Ptr inputs
Dim Shared As GLuint surface, cloud, rock
Dim Shared As GLUquadricObj Ptr Sphere
Dim Shared As GLfloat LightAmbient(3) => { 0.0f, 0.0f, 0.0f, 1.0f }
Dim Shared As GLfloat LightDiffuse(3) => { 1.0f, 1.0f, 1.0f, 1.0f }
Dim Shared As GLfloat LightPosition(3) => { 0.0f, 2.0f, -4f, 1.0f }
Dim Shared As Integer mouse_x, mouse_y

If fullscreen Then
App = sfRenderWindow_Create(Mode , @"Galactic Empire II - The Future", sfFullscreen, Settings)
Else
App = sfRenderWindow_Create(Mode , @"Galactic Empire II - The Future", sfClose, Settings)
EndIf
sfRenderWindow_ShowMouseCursor(App, sfFalse)
sfRenderWindow_SetCursorPosition(App, Mode.width/2,mode.height/2)

sfRenderWindow_PreserveOpenGLStates (App, sfTrue)

' Create text
Text = sfString_Create()
sfString_SetText(Text, "by AlZe")
sfString_SetSize(Text, 30)
sfString_SetColor(Text, sfColor_FromRGB(255,255,255))
sfString_SetPosition(Text, mode.width/2-50, mode.height - 50)

' Create background
Background = sfSprite_Create()
sfSprite_SetImage(Background, sfImage_CreateFromFile("background.jpg"))
sfSprite_SetScale(Background, Mode.width/sfSprite_GetWidth(Background),Mode.height/SfSprite_GetHeight(Background))

' Create cursor
Cursor = sfSprite_Create()
sfSprite_SetImage(Cursor, sfImage_CreateFromFile("cursor.png"))

' Create title
Title = sfSprite_Create()
sfSprite_SetImage(Title, sfImage_CreateFromFile("title.png"))
sfSprite_SetPosition(Title, 50, -5)

' Create history
History = sfSprite_Create()
sfSprite_SetImage(History, sfImage_CreateFromFile("history.png"))
sfSprite_SetPosition(History, 25, 175)
sfSprite_SetScale(History, 0.5, 0.5)

' Create textures
Image = sfImage_CreateFromFile("surface.png")
glGenTextures(1, @surface)
glBindTexture(GL_TEXTURE_2D, surface)
gluBuild2DMipmaps(GL_TEXTURE_2D, GL_RGBA, sfImage_GetWidth(Image), sfImage_GetHeight(Image), GL_RGBA, GL_UNSIGNED_BYTE, sfImage_GetPixelsPtr(Image))
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR)
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR_MIPMAP_LINEAR)

Image = sfImage_CreateFromFile("clouds.jpg")
glGenTextures(1, @cloud)
glBindTexture(GL_TEXTURE_2D, cloud)
gluBuild2DMipmaps(GL_TEXTURE_2D, GL_RGBA, sfImage_GetWidth(Image), sfImage_GetHeight(Image), GL_RGBA, GL_UNSIGNED_BYTE, sfImage_GetPixelsPtr(Image))
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR)
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR_MIPMAP_LINEAR)

Image = sfImage_CreateFromFile("rock.jpg")
glGenTextures(1, @rock)
glBindTexture(GL_TEXTURE_2D, rock)
gluBuild2DMipmaps(GL_TEXTURE_2D, GL_RGBA, sfImage_GetWidth(Image), sfImage_GetHeight(Image), GL_RGBA, GL_UNSIGNED_BYTE, sfImage_GetPixelsPtr(Image))
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR)
glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR_MIPMAP_LINEAR)

' Enable Z-buffer read and write
glDepthMask(GL_TRUE)
glClearDepth(1.f)

' Setup a perspective projection
glMatrixMode(GL_PROJECTION)
glLoadIdentity()
gluPerspective(60.f, 1.33f, 1.f, 500.f)

' Setup light
glLightfv(GL_LIGHT1, GL_AMBIENT, @LightAmbient(0))
glLightfv(GL_LIGHT1, GL_DIFFUSE, @LightDiffuse(0))
glLightfv(GL_LIGHT1, GL_POSITION, @LightPosition(0))
glEnable(GL_LIGHTING)
glEnable(GL_LIGHT1)

' Bind our texture
glEnable(GL_TEXTURE_2D)
glShadeModel(GL_SMOOTH)
glBlendFunc(GL_SRC_ALPHA,GL_ONE)
glEnable(GL_DEPTH_TEST)

' Create sphere
Sphere = gluNewQuadric()
gluQuadricNormals(Sphere, GL_SMOOTH)
gluQuadricTexture(Sphere, GL_TRUE)

'glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_REPEAT)
'glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_REPEAT)

glTexGeni(GL_S, GL_TEXTURE_GEN_MODE, GL_SPHERE_MAP)
glTexGeni(GL_T, GL_TEXTURE_GEN_MODE, GL_SPHERE_MAP)

' Create clock
Clock = sfClock_Create()

' Load and play music
music = sfMusic_CreateFromFile("music.ogg")
sfMusic_Play(music)
sfMusic_SetLoop(music, sfTrue)
sfMusic_SetVolume(music, 100)

' Start game loop
While (sfRenderWindow_IsOpened(App))

' Process events
While sfRenderWindow_GetEvent(App, @Event)

' Close window : exit
If Event.Type_ = sfEvtClosed Then sfRenderWindow_Close(App)

' Escape key : exit
If Event.Type_ = sfEvtKeyPressed And Event.Key.Code = sfKeyEscape Then sfRenderWindow_Close(App)

' Adjust the viewport when the window is resized
'If Event.Type_ = sfEvtResized Then glViewport(0, 0, Event.Size.Width_, Event.Size.Height)
Wend

' Draw background
sfRenderWindow_DrawSprite(App, Background)

' Clear depth buffer
glClear(GL_DEPTH_BUFFER_BIT)
glMatrixMode(GL_MODELVIEW)

' Draw planet surface
glLoadIdentity()
glBindTexture(GL_TEXTURE_2D, surface)
glColor4f(1.f, 1.f, 1.f, 1.f)
glDisable(GL_BLEND)
glTranslatef(2.0f, -1.0f, -3.0f)
glRotatef(-90, 1.f, 0.f, 0.f)
glRotatef(sfClock_GetTime(Clock), 0.f, 0.f, 1.f)
gluSphere(Sphere, 1.975f, 64, 64)

' Draw planet cloud
glLoadIdentity()
glBindTexture(GL_TEXTURE_2D, cloud)
glColor4f(1.f, 1.f, 1.f, 1.f)
glEnable(GL_BLEND)
glTranslatef(2.0f, -1.0f, -3.0f)

glRotatef(-90, 1.f, 0.f, 0.f)
glRotatef(sfClock_GetTime(Clock)*2, 0.f, 0.f, 1.f)
gluSphere(Sphere, 2f, 64, 64)

' Draw rock
glLoadIdentity()
glBindTexture(GL_TEXTURE_2D, rock)
glColor4f(1.f, 1.f, 1.f, 1.0f)
glDisable(GL_BLEND)
glTranslatef(2.0f, -1.0f, -3.0f)
glRotatef(sfClock_GetTime(Clock)* 10, 0.f, 1.f, 0.f)
glTranslatef(0.0f, 0.0f, -4f)
glRotatef(-90, 1.f, 0.f, 0.f)
glRotatef(sfClock_GetTime(Clock)*5, 0.f, 0.f, 1.f)
gluSphere(Sphere, 0.25f, 32, 32)

' Draw border
shape = sfShape_CreateRectangle(0,0,mode.width,mode.height/5,sfColor_FromRGB(0,0,0),1,sfColor_FromRGB(150,150,150)): sfRenderWindow_DrawShape(App, shape): sfShape_Destroy(shape)
shape = sfShape_CreateRectangle(0,mode.height-mode.height/5,mode.width,mode.height,sfColor_FromRGB(0,0,0),1,sfColor_FromRGB(150,150,150)): sfRenderWindow_DrawShape(App, shape): sfShape_Destroy(shape)

' Draw title
sfRenderWindow_DrawSprite(App, Title)

' Draw history
sfRenderWindow_DrawSprite(App, History)

Inputs = sfRenderWindow_GetInput(App)
mouse_x = sfInput_GetMouseX(Inputs)
mouse_y = sfInput_GetMouseY(Inputs)

' Draw text
sfString_SetText(Text, "by AlZe")
sfString_SetSize(Text, 30)
sfString_SetColor(Text, sfColor_FromRGB(255,255,255))
sfString_SetPosition(Text, mode.width/2-50, mode.height - 50)
sfRenderWindow_DrawString(App, Text)

If mouse_x >= sfSprite_GetX(History) And mouse_x <= sfSprite_GetX(History) + sfSprite_GetWidth(History) And _
mouse_y >= sfSprite_GetY(History) And mouse_y <= sfSprite_GetY(History) + sfSprite_GetHeight(History) Then
sfString_SetSize(Text, 25)
sfString_SetColor(Text, sfColor_FromRGB(0,100,255))
sfString_SetText(Text, "You've just seen the beginning..")
sfString_SetPosition(Text, 50, 400)
sfRenderWindow_DrawString(App, Text)
sfString_SetText(Text, "Prepare for something bigger..")
sfString_SetPosition(Text, 50, 450)
sfRenderWindow_DrawString(App, Text)
EndIf

' Draw cursor
sfSprite_SetPosition(Cursor, mouse_x, mouse_y)
sfRenderWindow_DrawSprite(App, Cursor)

sfRenderWindow_Display(App)
Wend

' Destroy textures
glDeleteTextures(1, @surface)
glDeleteTextures(1, @cloud)
glDeleteTextures(1, @rock)